【Shadertoy】レイマーチング基礎②

// 球の距離関数
// オブジェクトの中心を原点とした時の引数の位置と球の距離を返す
float sphere_d(vec3 pos, float size)
{
    float d0 = length(pos + vec3( 0.5, 0.0, 0.0)) - size;
    float d1 = length(pos + vec3(-0.5, 0.0, 0.0)) - size;

    return min(d0, d1);
}

float box_d(vec3 pos, vec3 size)
{
    vec3 q = abs(pos) - size;
    return length(max(q, 0.0)) + min(max(q.x, max(q.y, q.z)), 0.0);
}

// 球の距離関数
// オブジェクトの中心を原点とした時の引数の位置と球の距離を返す
float sphere_d(vec3 pos, float size)
{
    return length(pos) - size;
}

// 箱型の距離関数
float box_d(vec3 pos, vec3 size)
{
    vec3 q = abs(pos) - size;
    return length(max(q, 0.0)) + min(max( q.x, max(q.y, q.z)), 0.0);
}

// 距離関数をまとめたもの
float distance(vec3 pos, float size)
{
    return min(box_d(pos + vec3(  0.5, 0.0, 0.0), vec3(size)),
            sphere_d(pos + vec3( -0.5, 0.0, 0.0), size));
}

// レイがぶつかった位置を偏微分をして球の法線ベクトルを計算
vec3 getNormal(vec3 pos, float size)
{
    float delta = 0.0001;
    return normalize(vec3(
            distance(pos, size) - distance(vec3(pos.x - delta, pos.y, pos.z), size),
            distance(pos, size) - distance(vec3(pos.x, pos.y - delta, pos.z), size),
            distance(pos, size) - distance(vec3(pos.x, pos.y, pos.z - delta), size)
        ));
}

void mainImage( out vec4 fragColor, in vec2 fragCoord )
{
    // 描画位置がpxで返ってくるので-1.0 ~ +1.0に正規化
    vec2 pos = (fragCoord.xy * 2.0 - iResolution.xy) / min(iResolution.x, iResolution.y);
    vec3 col = vec3(0.03);
    
    // ライトの方向と色を決定
    vec3 lightDir = normalize(vec3(0.4, 1.0, 0.8));
    vec3 lightCol = vec3(0.9);
    
    // カメラの位置
    vec3 cPos = vec3(0.0,  0.0,  2.0);

    // レイの方向(カメラから描画位置へのベクトル)を決定
    vec3 rayDir = normalize(vec3(pos, 0.0) - cPos);
    vec3 cur = cPos;
    
    // 描画するオブジェクトのサイズ
    float size = 0.3;

    // 今回はレイの進める回数が最大128回
    for (int i = 0; i < 128; i++)
    {
        // レイの先端と球の距離を計測
        float d1 = distance(cur, size);

        // 距離が限りなく0に近い＝レイとオブジェクトが衝突している
        if (d1 < 0.001)
        {
            // レイが衝突した位置における法線ベクトルを取得
            vec3 normal = getNormal(cur, size);
            
            // 法線ベクトルとライトのベクトルで内積をとる(ランバート反射)
            float diff = dot(normal, lightDir);

            // 内積結果とライトの色をかけて描画色を決定
            col = vec3(diff) * lightCol;
            break;
        }
        // レイを進める
        cur += rayDir * d1;
    }

    fragColor = vec4(col, 1.0);
}

float distance(vec3 pos, float size)
{
    float d0 = sphere_d(pos + vec3( 0.0, 0.0, 0.0), 0.4);
    float d1 =    box_d(pos + vec3( 0.0, 0.0, 0.0), vec3(size));
    
    return max(d0, d1);
}

float distance(vec3 pos, float size)
{
    float d0 = sphere_d(pos + vec3( 0.0, 0.0, 0.0), 0.41);
    float d1 =    box_d(pos + vec3( 0.0, 0.0, 0.0), vec3(size));

    return max(-d0, d1);
}